【VBScript】パワーポイントファイル一覧のExcel作るには

Option Explicit
Main
Public Sub Main()
    'パワポファイルをリストアップ
    Dim pp, stPath, stPp, vBuf, sh, vOut(), lCnt
    stPath = "C:\test"

    Dim oExcel, Bk
    '①Excel用のインスタンスを生成
    Set oExcel = CreateObject("Excel.Application")
    '②ブックを新規で作成
    Set Bk = oExcel.Workbooks.Add
    '③シートを把握
    Set sh = Bk.Worksheets(1)
    Set pp = CreateObject("PowerPoint.Application")
    
    Dim FSO, oFolder, oFile
    '④VBScriptではDir関数は使えないので、地道にFileSystemObjectを使う
    Set FSO = CreateObject("Scripting.FileSystemObject")
    '⑤フォルダのオブジェクトを把握する
    set oFolder = FSO.GetFolder(stPath)

    lCnt = 0
    '⑥フォルダの中のファイル一つ一つを確認していく
    For Each oFile In oFolder.Files
        stPp = oFile.Name
        '⑦ファイルの拡張子がpptxだったら
        If FSO.GetExtensionName(oFile.Path) ="pptx" Then 
            vBuf = Split(stPp, "-") 'ハイフン「-」で分割する---⑧
            ReDim Preserve vOut(2, lCnt) '---⑨
            vOut(0, lCnt) = "'" & vBuf(1)   '⑩ゼロで始まる数字を文字列と認識してもらうために’つける
            vOut(1, lCnt) = Replace(vBuf(2), ".pptx", "")
            vOut(2, lCnt) = GetText(pp, stPath & "\" & stPp)
        
            lCnt = lCnt + 1
        End If
    Next
    
    sh.Cells(2, 2).Resize(lCnt, 3).Value = oExcel.WorksheetFunction.Transpose(vOut)   '---⑪Transposeで行と列を入れ替える
    sh.Cells(1, 2).Resize(1, 3).Value = Array("ナンバー", "標題", "内容") '---⑫
    pp.Quit
    Set pp = Nothing
    Set sh = Nothing
    Set Bk = Nothing
    '⑬Excelは非表示なので、表示するように設定を変えておく
    oExcel.Visible = True
    Set oExcel = Nothing
    WScript.Quit

End Sub
'↓⑭VBAと変えたのは型をなくしたところだけです
Private Function GetText(ByRef pp, ByVal stFullPath)
    Dim Obj
    Dim oShape
    
    Set Obj = pp.Presentations.Open(stFullPath)
    For Each oShape In Obj.Slides(1).Shapes
        If oShape.HasTextFrame Then
            GetText = Replace(oShape.TextFrame.TextRange.Text, "［結果］", "")
            Exit For
        End If
    Next
    
    Obj.Close
    Set Obj = Nothing
End Function