【InternetExplorer】地図の距離と時間を取得する【Seleniumなしで】【WebDriverなしで】

Option Explicit
'ワークシートに表示する情報のヘッダ
Enum e
    出発地 = 1
    目的地
    時間
    距離
    TheEnd = 距離
End Enum

'InternetExplorer
Public ie As InternetExplorer
'
'作成：野口香
'作成：2023/04/21
'
Public Sub GetMap()
    '作業用シート
    Dim sh As Worksheet
    Set sh = ThisWorkbook.Worksheets(1)
    
    'InternetExplorerを用意
    Set ie = New InternetExplorer
    
    'IE(InternetExplorer)を表示する
    ie.Visible = True
    
    'GoogleMapのURLへ遷移
    ie.navigate "https://www.google.co.jp/maps/dir///@36.3911651,139.0625882,17.98z/data=!4m2!4m1!3e0"
    Call ieWaitTime 'ieの読み込み待ち
    
    'ブラウザを最大サイズに。これをすると手動で元のサイズに戻せない。戻すときはFullScreen = False
    'デバッグ中、残ってしまったブラウザを終了させるときはAlt+F4
    ie.FullScreen = True
    Call ieWaitTime 'ieの読み込み待ち
    
    '前回までの情報をクリアしておく
    Const clHeader As Long = 2  'ヘッダ行の行番号
    sh.Range(sh.Cells(clHeader + 1, e.時間), sh.Cells(sh.Rows.Count, e.TheEnd)).ClearContents
    
    'Loop開始前、準備
    Dim ii As Long, lRow As Long
    Const cstStart As Long = 3
    lRow = sh.Cells(cstStart, e.目的地).End(xlDown).Row    '調査対象のレコード件数を把握する
    If lRow = sh.Rows.Count Then    '行数が最大値の場合、レコードが1件だけということなので、修正。
        lRow = cstStart
    End If
    
    Dim el As HTMLInputElement, xp As XPath
    Dim bn As HTMLButtonElement, te As HTMLTextElement
    Dim html As HTMLDocument
    Set html = New HTMLDocument
    Set html = ie.document
    
    'Loop突入
    For ii = cstStart To lRow
        
        '出発地
        Set el = html.querySelector("#sb_ifc50 > input")
        Call ieWaitTime 'ieの読み込み待ち

        el.Value = sh.Cells(ii, e.出発地).Value
        Call ieWaitTime 'ieの読み込み待ち
        
        '目的地
        Set el = html.querySelector("#sb_ifc51 > input")
        Call ieWaitTime 'ieの読み込み待ち
        
        el.Value = sh.Cells(ii, e.目的地).Value
        Call ieWaitTime 'ieの読み込み待ち
        el.Focus    'このFocusがないと出発地と目的地のInputTextがdeleteされてしまうので。
        
        '検索ボタンをクリック
        Set bn = html.querySelector("#directions-searchbox-1 > button.mL3xi")
        Call ieWaitTime 'ieの読み込み待ち
        bn.Click
        Call ieWaitTime 'ieの読み込み待ち
        
        'Webサイトの表示情報が更新されたので、いったんHtml.documentを取り直す←本来これはいらないはずだけど、次の「時間を取得」のステップでエラーが頻発したので入れてみた。
        Set html = ie.document
        Call ieWaitTime 'ieの読み込み待ち
       
        '時間を取得
        Set te = html.querySelector("#section-directions-trip-0 > div.MespJc > div:nth-child(1) > div.XdKEzd > div:nth-child(1) > span:nth-child(1)")
        Call ieWaitTime 'ieの読み込み待ち
        sh.Cells(ii, e.時間).Value = te.innerText
        Call ieWaitTime 'ieの読み込み待ち
        
        '距離を取得
        Set te = html.querySelector("#section-directions-trip-0 > div.MespJc > div:nth-child(1) > div.XdKEzd > div:nth-child(2) > div")
        Call ieWaitTime 'ieの読み込み待ち
        sh.Cells(ii, e.距離).Value = te.innerText
        Call ieWaitTime 'ieの読み込み待ち

    Next ii
    
    '終了
    ie.Quit
    
    'オブジェクト解放
    Set sh = Nothing
    Set te = Nothing: Set bn = Nothing
    Set ie = Nothing: Set el = Nothing
    
    '終了メッセージ
    MsgBox "終了"
    
End Sub

'読込待ち処理
Public Function ieWaitTime()

    'ieがBusy(処理中なら)DoEventsで待機
    Do While ie.Busy = True
        DoEvents
    Loop
    
    'ieがREADYSTATE_COMPLETE(全データ読込完了になるまで)DoEventsで待機
    Do While ie.readyState <> READYSTATE_COMPLETE
        DoEvents
    Loop
    
    '操作が安定するよう念を入れて待機
    Application.Wait [Now() + "00:00:01"]
End Function

sh.Cells(ii, e.時間).Value = te.innerText