【WordVBA】相互参照に着色

Option Explicit

Private myRibbon As Office.IRibbonUI
Private flg As Boolean
 
Public Sub myRbn_onLoad(ribbon As IRibbonUI)
  Set myRibbon = ribbon
  flg = True
  myRibbon.Invalidate ' リボンの表示を更新する
End Sub
 
Public Sub myTgl_onAction(control As IRibbonControl, pressed As Boolean)
    flg = pressed
    SetHighlight
End Sub
 
Public Sub myTgl_getPressed(control As IRibbonControl, ByRef returnedVal)
    returnedVal = flg
End Sub
'
'検索して置換で蛍光ペンを引く
'
Private Sub SetHighlight()
    
    '画面制御
    Application.ScreenUpdating = False
    
    'フィールドコードを表示
    ActiveWindow.View.ShowFieldCodes = Not ActiveWindow.View.ShowFieldCodes
    
    '蛍光ペンの色を選択しておく
    If flg Then
        Options.DefaultHighlightColorIndex = wdYellow       '黄色
    Else
        Options.DefaultHighlightColorIndex = wdNoHighlight  '無色
    End If
    
    Dim Rng As Range
    
    '変換範囲
    If Selection.Start = Selection.End Then
        Set Rng = ActiveDocument.Range   '範囲選択しなければ文書全体
    Else
        Set Rng = Selection.Range    '選択された範囲内のみ
    End If
    
    '検索して置換（置換後の文字列は蛍光ペンが引かれる）
    Rng.Find.ClearFormatting
    Rng.Find.Replacement.ClearFormatting
    Rng.Find.Replacement.Highlight = True
    With Rng.Find
        .Text = "^d Ref"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = False
        .MatchFuzzy = False
    End With
    Rng.Find.Execute Replace:=wdReplaceAll
    
    '後始末
    Set Rng = Nothing
    
    'フィールドコードを非表示
    ActiveWindow.View.ShowFieldCodes = Not ActiveWindow.View.ShowFieldCodes
    
    '画面制御復帰
    Application.ScreenUpdating = True
End Sub