【SeleniumBasic】地図のオプションを指定して距離と時間を取得する【Excel】

Option Explicit
'ワークシートに表示する情報のヘッダ
Enum e
    出発地 = 1
    目的地
    高速時間
    高速距離
    下道時間
    下道距離
    TheEnd = 下道距離
End Enum
'
'作成：野口香
'作成：2023/10/07
'
Public Sub GetMap()
    '作業用シート
    Dim sh As Worksheet
    Set sh = ThisWorkbook.Worksheets(1)
    
    'Seleniumを用意
    Dim driver As Object
    Set driver = CreateObject("Selenium.WebDriver")
    
    'スクレイピングのお作法・・・wait時間(単位：ms)
    Const clSHORT_WAIT As Long = 500  '0.5sec。
    Const clLONG_WAIT As Long = 5000  '5sec。
   
    
    'Chromeをスタート
    driver.Start "Chrome"
    
    'ブラウザを最大サイズに
    driver.Window.Maximize
    
    '前回までの情報をクリアしておく
    Const clHeader As Long = 2  'Excelシートのデータのある表の列見出しのある行の行番号
    Const cstStart As Long = clHeader + 1      'Excelシートのデータが入っている行の1番目の行番号。clHeaderの次の行なのでプラス1
    sh.Range(sh.Cells(cstStart, e.高速時間), sh.Cells(sh.Rows.Count, e.TheEnd)).ClearContents
    
    'GoogleMapのURL
    Const cstUrl As String = "https://www.google.co.jp/maps"
    driver.Get cstUrl
    driver.Wait clSHORT_WAIT
    
    'ルート検索ボタンを押す
    driver.FindElementById("hArJGc").Click
    driver.Wait clSHORT_WAIT

    'Loop開始前、準備
    Dim lRow As Long
    lRow = sh.Cells(cstStart, e.目的地).End(xlDown).Row
    If lRow = sh.Rows.Count Then
        lRow = cstStart
    End If
    
    'ループ内で使うオブジェクト群の宣言
    Dim el As Object
    Dim Keys As Object      'SendKeysで使うSeleniumのキーボード操作用オブジェクト
    Set Keys = CreateObject("Selenium.Keys")
    Dim myBy As Object      'IsElementPresentで使う。IsElementPresentは要素が存在するか調べるメソッドで、引数にSlenium.Byオブジェクトを使う。
    Set myBy = CreateObject("Selenium.By")
    Dim ii As Long
    
    For ii = cstStart To lRow
        
        '出発地
        Set el = driver.FindElementByXPath("//*[@id=""sb_ifc50""]/input")
        el.Clear
        driver.Wait clSHORT_WAIT
        el.SendKeys sh.Cells(ii, e.出発地).Value
        driver.Wait clSHORT_WAIT
        
        '目的地
        Set el = driver.FindElementByXPath("//*[@id=""sb_ifc51""]/input")
        el.Clear
        driver.Wait clSHORT_WAIT
        el.SendKeys sh.Cells(ii, e.目的地).Value
        driver.Wait clSHORT_WAIT
        
        ' 検索ボタンをクリック
        driver.FindElementByXPath("//*[@id=""directions-searchbox-1""]/button[1]").Click
        driver.Wait clLONG_WAIT '少し長めに待つ
        
        '高速道路のオプションの要素が存在するかどうか
        If driver.IsElementPresent(myBy.XPath("//*[@id=""pane.directions-options-avoid-highways""]")) Then
            '既にオプションが表示されている
        Else
            'オプションが表示されていない
            '→オプションを表示する
            driver.FindElementByXPath("//*[@id=""QA0Szd""]/div/div/div[1]/div[2]/div/div[1]/div/div/div[2]/button").Click
            driver.Wait clSHORT_WAIT
        End If
        
        '高速道路を使わないにチェック
        driver.FindElementByXPath("//*[@id=""pane.directions-options-avoid-highways""]").SendKeys Keys.Space
        
        '下道時間を取得
        sh.Cells(ii, e.下道時間).Value = driver.FindElementByXPath("//*[@id=""section-directions-trip-0""]/div[1]/div/div[1]/div[1]").Text
        driver.Wait clSHORT_WAIT
        
        '下道距離を取得
        sh.Cells(ii, e.下道距離).Value = driver.FindElementByXPath("//*[@id=""section-directions-trip-0""]/div[1]/div/div[1]/div[2]/div").Text
        driver.Wait clSHORT_WAIT

        '高速道路を使用しないのチェックを外す(高速道路を使う)
        driver.FindElementByXPath("//*[@id=""pane.directions-options-avoid-highways""]").SendKeys Keys.Space
    
        '高速時間を取得
        sh.Cells(ii, e.高速時間).Value = driver.FindElementByXPath("//*[@id=""section-directions-trip-0""]/div[1]/div/div[1]/div[1]").Text
        driver.Wait clSHORT_WAIT
        
        '高速距離を取得
        sh.Cells(ii, e.高速距離).Value = driver.FindElementByXPath("//*[@id=""section-directions-trip-0""]/div[1]/div/div[1]/div[2]/div").Text
        driver.Wait clSHORT_WAIT
    Next ii
    
    '終了
    driver.Close
    
    'オブジェクト解放
    Set sh = Nothing
    Set driver = Nothing
    Set myBy = Nothing
    Set Keys = Nothing
    Set el = Nothing
    
    '終了メッセージ
    MsgBox "終了"
    
End Sub

driver.FindElementByXPath("//*[@id=""pane.directions-options-avoid-highways""]").SendKeys Keys.Space

Dim Keys As Object      'SendKeysで使うSeleniumのキーボード操作用オブジェクト

Dim Keys As Keys

Set Keys = CreateObject("Selenium.Keys")

Set Keys = New Keys

        '高速道路を使わないにチェック
        driver.FindElementByXPath("//*[@id=""pane.directions-options-avoid-highways""]").SendKeys Keys.Space

        '高速道路を使用しないのチェックを外す(高速道路を使う)
        driver.FindElementByXPath("//*[@id=""pane.directions-options-avoid-highways""]").SendKeys Keys.Space

Enum f
    START_POS = 1  '出発地
    END_POS         '目的地
    HIGHWAY_TIME    '高速時間
    HIGHWAY_DURATION '高速距離
    LOCAL_TIME      '下道時間
    LOCAL_DURATION  '下道距離
    TheEnd = LOCAL_DURATION
End Enum

Enum e
    出発地 = 1
    目的地
    高速時間
    高速距離
    下道時間
    下道距離
    TheEnd = 下道距離
End Enum