【SeleniumBasic】地図の距離と時間を取得する【Excel】

Option Explicit
'ワークシートに表示する情報のヘッダ
Enum e
    出発地 = 1
    目的地
    時間
    距離
    TheEnd = 距離
End Enum
'
'作成：野口香
'作成：2023/04/20
'
Public Sub GetMap()
    '作業用シート
    Dim sh As Worksheet
    Set sh = ThisWorkbook.Worksheets(1)
    
    'Seleniumを用意
    Dim driver As Object
    Set driver = CreateObject("Selenium.WebDriver")
    
    'スクレイピングのお作法・・・wait時間
    Const clWAIT As Long = 500
    
    'Chromeをスタート
    driver.Start "Chrome"
    
    'ブラウザを最大サイズに
    driver.Window.Maximize
    
    '前回までの情報をクリアしておく
    Const clHeader As Long = 2
    sh.Range(sh.Cells(clHeader + 1, e.時間), sh.Cells(sh.Rows.Count, e.TheEnd)).ClearContents
    
    'GoogleMapのURL
    Const cstUrl As String = "https://www.google.co.jp/maps/dir///@36.3911651,139.0625882,17.98z/data=!4m2!4m1!3e0"
    driver.Get cstUrl
    driver.Wait clWAIT
    
    'Loop開始前、準備
    Dim ii As Long, lRow As Long
    Const cstStart As Long = 3
    lRow = sh.Cells(cstStart, e.目的地).End(xlDown).Row
    If lRow = sh.Rows.Count Then
        lRow = cstStart
    End If
    
    '出発地
    Dim el As Object
    
    For ii = cstStart To lRow
    
        Set el = driver.FindElementByXPath("//*[@id=""sb_ifc50""]/input")
        el.Clear
        driver.Wait clWAIT
        el.SendKeys sh.Cells(ii, e.出発地).Value
        driver.Wait clWAIT
        
        '目的地
        Set el = driver.FindElementByXPath("//*[@id=""sb_ifc51""]/input")
        el.Clear
        driver.Wait clWAIT
        el.SendKeys sh.Cells(ii, e.目的地).Value
        driver.Wait clWAIT
        
        '検索ボタンをクリック
        driver.FindElementByXPath("//*[@id=""directions-searchbox-1""]/button[1]").Click
        driver.Wait clWAIT * 10 '少し長めに待つ
        
        '時間を取得
        sh.Cells(ii, e.時間).Value = driver.FindElementByXPath("//*[@id=""section-directions-trip-0""]/div[1]/div[1]/div[1]/div[1]/span[1]").Text
        driver.Wait clWAIT
        
        '距離を取得
        sh.Cells(ii, e.距離).Value = driver.FindElementByXPath("//*[@id=""section-directions-trip-0""]/div[1]/div[1]/div[1]/div[2]/div").Text
        driver.Wait clWAIT

    Next ii
    '終了
    driver.Close
    
    'オブジェクト解放
    Set sh = Nothing
    Set driver = Nothing
    Set el = Nothing
    
    '終了メッセージ
    MsgBox "終了"
    
End Sub