【SeleniumBasic】Google検索してシートに書き出す【VBA】【追記有】

Option Explicit
'
'作成：野口香
'作成：2023/04/16
'
Public Sub Google検索()
    '作業用シート
    Dim sh As Worksheet
    Set sh = ThisWorkbook.Worksheets(1)
    
    'Seleniumを用意
    Dim driver As Object
    Set driver = CreateObject("Selenium.WebDriver")
    
    'スクレイピングのお作法・・・wait時間
    Const clWAIT As Long = 100
    
    'Chromeをスタート
    driver.Start "Chrome"
    
    'ブラウザを最大サイズに
    driver.Window.Maximize
    
    '検索文字をワークシートから取得
    Dim stMoji As String
    stMoji = sh.Range("B1").Value
    
    'ワークシートの前回検索結果をクリアコンテンツ
    sh.Range("A1").Resize(sh.Rows.Count, 1).ClearContents
    
    'GoogleURL
    Dim stUrl As String
    stUrl = "https://www.google.com/search?q=" & stMoji
    
    '検索
    driver.Get stUrl
    driver.Wait clWAIT
    
    '検索結果を取得
    Dim elements As Selenium.WebElements
    Set elements = driver.FindElementsByCss(".yuRUbf h3")
    driver.Wait clWAIT
    
    '検索結果をExcelに転記
    Dim Cnt As Long
    Cnt = elements.Count
    Dim ii As Long
    Dim lRow As Long
    lRow = 2
    For ii = 1 To Cnt
        sh.Cells(lRow, 1).Value = elements(ii).Text
        lRow = lRow + 1
    Next ii
    
    '次へがあるか調査
    Dim myBy As Selenium.By
    Set myBy = New Selenium.By
    Do While driver.IsElementPresent(myBy.Css("#pnnext"))
        driver.Wait clWAIT
        '次へがあるなら次へをクリック
        driver.FindElementByCss("#pnnext").Click
        driver.Wait clWAIT
        
        '検索結果を取得
        Set elements = driver.FindElementsByCss(".yuRUbf h3")
        driver.Wait clWAIT
        
        '検索結果をExcelに書き込む
        Cnt = elements.Count
        For ii = 1 To Cnt
            sh.Cells(lRow, 1).Value = elements(ii).Text
            lRow = lRow + 1
        Next ii
            
    Loop
    '終了
    driver.Close
    
    'オブジェクト解放
    Set sh = Nothing
    Set driver = Nothing
    Set myBy = Nothing
    
    '終了メッセージ
    MsgBox "終了"
End Sub